EDN -- 11.23.95 compare spice simulation to graphical template

Design Ideas: November 23, 1995

Compare spice simulation to graphical template

Bashir Al-Hashimi,
School of Engineering, Staffordshire University
Stafford, UK

A former EDN Design Idea (see Ref 1) described how to use the Laplace-transform feature of PSpice's analog-behavioral-modeling option to compare the simulated frequency response of a circuit with its ideal transfer function. This approach is useful, provided that you know the circuit's transfer function. However, you often design circuits, particularly filters, with a frequency response that meets a particular shape in the form of a graphical template. In this case, you can use another behavioral-modeling feature to plot a given graphical frequency characteristic and compare it with a circuit's simulated response.

Listing 1 shows the attenuation-frequency-characteristics template of a typical 70-MHz Intelsat bandpass filter in PSpice. The graphical template consists of a look-up table, where each entry in the table consists of a frequency, magnitude (decibels), and phase (degree) value. Frequency look-up tables are possible in PSpice using the frequency-response-statement (FREQ) part of the analog- behavioral-modeling option. The Emx voltage-controlled voltage source describes the filter maximum-attenuation template with the input at node 1 and the output at node 2. Similarly, source Emi defines the minimum-attenuation filter template with the input at node 1 and the output at node 3. Note that this simulation doesn't take the filter's phase-characteristics template into account. Therefore, each phase-shift entry in Listing 1 is 0.

LISTING 1—PSPICE FREQUENCY-CHARACTERISTICS TEMPLATE OF A
70-MHz INTELSAT BANDPASS FILTER

VIN 1 0 AC 1
.AC LIN 500 20E6 120E6 ;frequency response analysis from 20 MHz to 120MHz
*
Emx 2 0 FREQ {V(1)}=(52E6,-50,0)
+         (52.0001E6,-2.5,0)
+         (55.6E6,-1.2,0)
+         (65.2E6,-0.9,0)
+         (74.8E6,-0.9,0)
+         (84.4E6,-1.2,0)
+         (88E6,-2.5,0)
+         (88.0001E6,-50,0)         ;maximum attenuation template
*
Emi 3 0 FREQ {V(1)}=(40E6,-25,0)
+         (47.375E6,-10,0)
+         (52E6,0,0)
+         (55.6E6,0,0)
+         (65.2E6,-0.3,0)
+         (74.8E6,-0.3,0)
+         (84.4E6,0,0)
+         (88E6,0,0)
+         (92.625E6,-10,0)
+         (100E6,-25,0)         ;minimum attenuation template
*
R1 1 0 1G
R2 2 0 1G
R3 3 0 1G                       ;resistors needed to satisfy floating nodes rule
.END                            ;end of netlist

You plot the template by including a frequency-response-analysis (.AC) statement in the listing. Then, running Listing 1 and the input file of an LC passive filter designed to match the template specifications produces the plot in Figure 1. This plot shows that the designed filter is very close to meeting the required specification. The LC filter's design involves cascading two fifth-order lowpass and highpass elliptic filters. (DI #1795)

References

1. Jung, W, "Spice technique compares frequency responses," EDN, Nov 25, 1993, pg 188.

2. Al-Hashimi, B, The Art of Simulation Using PSpice: Analog & Digital, CRC Press, 1995, ISBN 0849378958.